/perf/kseta

__constant sampler_t sampler = CLK_NORMALIZED_COORDS_FALSE | CLK_ADDRESS_CLAMP | CLK_FILTER_NEAREST;

 

#define A(i, j) shmem[(i) * BLOCK_SIZE + (j)]

#define B(i, j) shmem[PPT * BLOCK_SIZE * BLOCK_SIZE + (i) * PPT * BLOCK_SIZE + (j)]

 

__kernel void multiply(__global float *res, __read_only image2d_t a, __read_only image2d_t b, unsigned long size, __local float *shmem) {

    float sum[PPT][PPT] = {0};

    

    int bx = get_group_id(0) * get_local_size(0) * PPT;

    int by = get_group_id(1) * get_local_size(1) * PPT;

    

    int tx = get_local_id(0);

    int ty = get_local_id(1);

 

    int i = get_global_id(1);

    int j = get_global_id(0);

 

    int x, y;

    int k, l, m;

 

 

    for(k = 0; k < size; k += BLOCK_SIZE) {

#pragma unroll PPT

        for (m = 0; m < PPT; ++m) {

            A(m * BLOCK_SIZE + ty, tx) = read_imagef(a, sampler, (int2)(k + tx, by + m * BLOCK_SIZE + ty)).x; //a[(by + m * BLOCK_SIZE + ty) * size + (k + tx)];

            B(ty, m * BLOCK_SIZE + tx) = read_imagef(b, sampler, (int2)(bx + m * BLOCK_SIZE + tx, k + ty)).x; //b[(k + ty) * size + (bx + m * BLOCK_SIZE + tx)];

        }

        

        barrier(CLK_LOCAL_MEM_FENCE);

        

//#pragma unroll PPT * BLOCK_SIZE

        for (l = 0; l < BLOCK_SIZE; ++l) {

#pragma unroll PPT

            for (y = 0; y < PPT; ++y) {

#pragma unroll PPT

                for (x = 0; x < PPT; ++x) {

                    sum[y][x]  += A(y * BLOCK_SIZE + ty, l) * B(l, x * BLOCK_SIZE + tx);

                }

            }

        }

 

        barrier(CLK_LOCAL_MEM_FENCE);

    }

    

#pragma unroll PPT

        for (y = 0; y < PPT; ++y) {

#pragma unroll PPT

            for (x = 0; x < PPT; ++x) {

                res[(by + y * BLOCK_SIZE + ty) * size + bx + x * BLOCK_SIZE + tx] = sum[y][x];

            }

        }

}