/perf/kseta

#define A(i, j) shmem[(i) * PPT * BLOCK_SIZE + (j)]

#define B(i, j) shmem[PPT * PPT * BLOCK_SIZE * BLOCK_SIZE + (i) * PPT * BLOCK_SIZE + (j)]

 

__kernel void multiply(__global float *res, __global float *a, __global float *b, unsigned long size, __local float *shmem) {

    float sum[PPT][PPT] = {0};

    

    int bx = get_group_id(0) * get_local_size(0) * PPT;

    int by = get_group_id(1) * get_local_size(1) * PPT;

    

    int tx = get_local_id(0);

    int ty = get_local_id(1);

 

    int i = get_global_id(1);

    int j = get_global_id(0);

 

    int x, y;

    int k, l;

 

 

    for(k = 0; k < size; k += PPT * BLOCK_SIZE) {

#pragma unroll PPT

        for (y = 0; y < PPT; ++y) {

#pragma unroll PPT

            for (x = 0; x < PPT; ++x) {

                A(y * BLOCK_SIZE + ty, x * BLOCK_SIZE + tx) = a[(by + y * BLOCK_SIZE + ty) * size + (k + x * BLOCK_SIZE + tx)];

                B(y * BLOCK_SIZE + ty, x * BLOCK_SIZE + tx) = b[(k + y * BLOCK_SIZE + ty) * size + (bx + x * BLOCK_SIZE + tx)];

            }

        }

        

        barrier(CLK_LOCAL_MEM_FENCE);

        

#pragma unroll PPT * BLOCK_SIZE

        for (l = 0; l < PPT * BLOCK_SIZE; ++l) {

#pragma unroll PPT

            for (y = 0; y < PPT; ++y) {

#pragma unroll PPT

                for (x = 0; x < PPT; ++x) {

                    sum[y][x]  += A(y * BLOCK_SIZE + ty, l) * B(l, x * BLOCK_SIZE + tx);

                }

            }

        }

 

        barrier(CLK_LOCAL_MEM_FENCE);

    }

    

#pragma unroll PPT

        for (y = 0; y < PPT; ++y) {

#pragma unroll PPT

            for (x = 0; x < PPT; ++x) {

                res[(by + y * BLOCK_SIZE + ty) * size + bx + x * BLOCK_SIZE + tx] = sum[y][x];

            }

        }

}