# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE="threads(+)"

#SDS
DISTUTILS_USE_SETUPTOOLS=no
#EDS

inherit distutils-r0 multiprocessing

VEC_P=cryptography_vectors-${PV}
DESCRIPTION="Library providing cryptographic recipes and primitives"
HOMEPAGE="https://github.com/pyca/cryptography/ https://pypi.org/project/cryptography/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
	test? ( mirror://pypi/c/cryptography_vectors/${VEC_P}.tar.gz )"

LICENSE="|| ( Apache-2.0 BSD )"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv s390 sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
IUSE="libressl idna"

RDEPEND="
	>=dev-python27/six-1.4.1[${PYTHON_USEDEP}]
	idna? ( >=dev-python27/idna-2.1[${PYTHON_USEDEP}] )
	$(python_gen_cond_dep '
		>=dev-python27/cffi-1.8:=[${PYTHON_USEDEP}]
	' 'python*')
	"
BDEPEND="
	test? (
		>=dev-python27/hypothesis-1.11.4[${PYTHON_USEDEP}]
		dev-python27/iso8601[${PYTHON_USEDEP}]
		dev-python27/pretend[${PYTHON_USEDEP}]
		dev-python27/pyasn1-modules[${PYTHON_USEDEP}]
		dev-python27/pytz[${PYTHON_USEDEP}]
		dev-python27/pytest-xdist[${PYTHON_USEDEP}]
	)"

distutils_enable_tests pytest

DEPEND="
	!libressl? ( >=dev-libs/openssl-1.0.2o-r6:0= )
	libressl? ( >=dev-libs/libressl-2.9.1:0= )
	"
RDEPEND+=${DEPEND}

DOCS=( AUTHORS.rst CONTRIBUTING.rst README.rst )

src_prepare() {
	default

	# work around availability macros not supported in GCC (yet)
	if [[ ${CHOST} == *-darwin* ]] ; then
		local darwinok=0
		if [[ ${CHOST##*-darwin} -ge 16 ]] ; then
			darwinok=1
		fi
		sed -i -e 's/__builtin_available(macOS 10\.12, \*)/'"${darwinok}"'/' \
			src/_cffi_src/openssl/src/osrandom_engine.c || die
	fi
#SDS
	sed -i -e 's/sys.version_info\[0\] == 2/sys.version_info[0] == 1/g' src/cryptography/__init__.py || die
#EDS
}

python_test() {
	local -x PYTHONPATH=${PYTHONPATH}:${WORKDIR}/${VEC_P}
	pytest -vv -n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" ||
		die "Tests fail with ${EPYTHON}"
}